Export database and settings after update

[necrox]

Is it possible to export ketarin's settings and applications once it has finished its updating work? I know there is the command line argument:

/export=FILENAME

But as I can see there is no possibility to use that argument as command for "After updating all applications".

[shawn]

No, but you could call a batch file or something. This is what I use:

@ECHO OFF

:variables
REM !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
FOR /F "tokens=2-4 delims=/ " %%a in ("%date%") DO SET MM=%%a&SET DD=%%b&SET YY=%%c
FOR /F "tokens=1-4 delims=:. " %%a in ("%time%") DO SET HH=%%a&SET NN=%%b&SET SS=%%c&SET LL=%%d
FOR /L %%a in (0,1,9) DO @IF "%HH%"=="%%a" SET HH=0%%a
SET timestamp=%YY%%MM%%DD%T%HH%%NN%%SS%

REM Export current settings
ketarin /export=ketarin-%timestamp%.xml

[necrox]

Thank you! After modification of the delimiter from / to ./ for %DATE% everything worked fine. That's because of my German Windows version.

 

@ECHO OFF

:variables
REM !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
FOR /F "tokens=2-4 delims=./ " %%a in ("%date%") DO SET MM=%%a&SET DD=%%b&SET YY=%%c
FOR /F "tokens=1-4 delims=:. " %%a in ("%time%") DO SET HH=%%a&SET NN=%%b&SET SS=%%c&SET LL=%%d
FOR /L %%a in (0,1,9) DO @IF "%HH%"=="%%a" SET HH=0%%a
SET timestamp=%YY%%MM%%DD%T%HH%%NN%%SS%

REM Export current settings
ketarin /export=ketarin-%timestamp%.xml

[Tomorrow]

This is what i use.Exports the database.Stops installers and removes startup items that were added by installations:

ketarin /export="Ketarin Database.xml"
sc config trustedinstaller start= demand
sc stop trustedinstaller
sc config msiserver start= demand
sc stop msiserver
reg import "D:\Resources\CMD\Delete StartUp Items.reg"

[necrox]

Is it possible to export the application settings too using the batch method?

[shawn]

Yes, but...you'd have to know each registry hive where the application settings are stored. This can be different between versions, much less operating systems. I use a batch script to export reg settings for various apps (such as DreamWeaver, WinSCP and Notepad++). I also call it from 4 different computers, XP, Vista and Win7 between them. Here's a nifty snippet you might find useful to check the current OS (which is important for assembling certain paths):

FOR /f "tokens=2 delims=.[" %%a IN ('ver') DO SET v=%%a
REM Win Vista/7
IF "%v%"=="Version 6" nircmdc elevate cmd /c "W:\GetData.bat"
REM Win NT, 2000, XP
IF "%v%"=="Version 5" CALL "W:\GetData.bat"

[shawn]

Here's an example export for WinSCP:

REGEDIT /E .\settings\winscp-%COMPUTERNAME%.reg "HKEY_CURRENT_USER\Software\Martin Prikryl"

[necrox]

Oh I see. It is the same as the import / export way on my windows unattended setup. Thank you for the hint!